Last week, we had our very first quiz – “How well do you know your LOOKUPs?“. I hope you have enjoyed it.Today lets understand the answers & explanations for this quiz.
First a summary of results (and controversies):
More than 3,200 people attempted the quiz. Roughly 45% of you got correct answers. That said there were 4 questions where 90% of you made mistakes. This is mainly because these questions & answer choices were ambiguous. As this is the first time I ran a quiz on Chandoo.org, it was a learning experience for me too. I promise to keep the questions & answer choices clearer next time
*Questions that are ambiguous are marked with a * below.
Here are the answers & explanations this quiz.
Q1. When would you use FALSE as 4th parameter in VLOOKUP
If your lookup table is in ascending order, then you can omit 4th parameter and VLOOKUP will find either exact or approximate match.We use 4th parameter as FALSE when our list may not be in any particular sort order and we are looking for exact matches.
So the answer is When my lookup list is not in any particular sort order
Related: Introduction to VLOOKUP – Syntax, explanation & examples
*Q2. Which of below formulas can be used to find if a value is available in a list of values
We can check whether a value is present in a list or not using any of below formulas.COUNTIF / COUNTIFS
- COUNTIF(range, value you are looking) will be >0 if value is available.
- Introduction to COUNTIF formula
- VLOOKUP(value you are looking, range, 1,false) will not be an error if value is available
- SUMPRODUCT(–(range=value you are looking)) will be >0
- Introduction to SUMPRODUCT formula
- MATCH(value you are looking, range,0) will not be an error
- Introduction to MATCH formula
Q3. You have a list of invoice numbers & amounts in a range A1:B100. Some of the invoice numbers are duplicated. You wrote VLOOKUP to find amount corresponding to an invoice number. If that invoice has 2 entries, then VLOOKUP will,
VLOOKUP will always find the first match (assuming you specified FALSE in last parameter).Related: Finding 2nd, 3rd matches using VLOOKUP.
Q4. To trap errors in VLOOKUP, we can use this formula.
We all want a world without traffic, crying babies & error messages. Alas, there are no Excel formulas for first 2, but we can suppress error messages for sure, by using any of below formulas:- IFERROR
- ISERROR
- ISNA
- IFNA (new in Excel 2013)
*Q5. You have a list with below columns
Although VLOOKUP is very powerful, it has one limitation. It can only search in left most column and get values from columns to right. To lookup on a column in middle and get values from either left or right, we can use below alternatives.Invoice ID, Customer ID, Amount, Due DateNow, you want to lookup the invoice ID for a given Customer ID. Which of below formulas you would use? Assume that your list is not in any particular order and there are no duplicate customer IDs.INDEX + MATCH formulas
- =INDEX(invoiceIDs, MATCH(thisID, customerIDs, 0))
- More on this technique
- =OFFSET(invoiceIDs, MATCH(thisID, customerIDs, 0),0,1,1)
- More on this technique, OFFSET formula explained
- =VLOOKUP(thisID,CHOOSE({2,1},invoiceIDs, customerIDs), 2, FALSE)
- More on this technique
Q6. You have a list of invoice numbers & amounts in the range A1:B100. Some of the invoice numbers are duplicated. You want to find the last invoice amount for a given invoice number. Which formulas you would use
To find the last invoice and its amount, we need to few ingredients:- Know how many invoices are there for given invoice number
- A helper column with invoice counts up to that point
=A1&”-”&COUNTIF($A$1:A1,A1)
This will tell us how many times each invoice number is repeated up to that point.
Now, use the VLOOKUP formula to find last invoice’s amount like this:
=VLOOKUP(this_invoice&”-”&COUNTIF(A1:A100, this_invoice), B1:C100, 2, false)
Related: Finding 2nd, 3rd … matches using VLOOKUP.
Q7. If the value you are looking up is not found, VLOOKUP will return #VALUE! error
Nah, it will return #N/A error.Q8. You have a list of employee names & their salary details.
in 5 columns – A1:E100.
Your friend gave you below VLOOKUP formula
What would be the output of this
Do you know that you can use arrays for 3rd parameter in VLOOKUP? When you do it, you will get values from all column numbers mentioned in the array. So we get Joyce’s salary, special allowance, travel allowance and bonus amounts.Employee name, Salary, Special Allowance, Travel Allowance, Bonusin 5 columns – A1:E100.
Your friend gave you below VLOOKUP formula
=SUMPRODUCT(VLOOKUP("Joyce", A1:E100, {2,3,4,5}, FALSE))What would be the output of this
When wrapped in SUMPRODUCT, this will just be the sum of all these numbers.
Related: Extracting values from multiple columns using VLOOKUP.
*Q9. You have a lot of customer data in range A1:Z1000. Col A has unique customer ID & rest of the 25 columns have data about that customer. You want to create a lookup sheet to show customer information. But you are too lazy to write 25 different VLOOKUPs. Which formula you will use along with VLOOKUP…
To get the value from 2nd column, we write =VLOOKUP(value to lookup, A1:Z1000, 2, false)To get 3rd column value, we need to replace 2 with 3.
What if we can write 1 formula and drag it side-ways so that 2 becomes 3,4…24,25?
Enter the COLUMNS() formula. It can be used to generate running numbers. So, our formula becomes,
=VLOOKUP(value to lookup, $A$1:$Z$1000, COLUMNS($A$1:A$1)+1, false)
now, you can just drag the VLOOKUP formula sideways and it will get you all the 25 values
Apart from COLUMNS(), you can also use ROWS(), COLUMN(), ROW() or simply a set of 25 numbers typed in a range and using cell references in place of 2,3,…24,25.
*Q10. You have 3 columns of data – Customer ID, Invoice ID & amount. You want to lookup by a combination of customer ID & invoice ID and fetch the corresponding amount. Which formula will help you?
You can use any of below formulas to do this:SUMIFS
=SUMIFS(amounts, customerIDs, this customer, invoiceIDs, this invocie)
SUMPRODUCT
=SUMPRODUCT(amounts, (customerIDs=this customer), (invoiceIDs=this invoice))
INDEX & MATCH
(Array formula)
{=INDEX(amounts, MATCH(this customer & this invoice, (customerIDs)&(invoiceIDs), 0)) }
Related: Various techniques for multi-condition lookups.
Want to master Lookup formulas?
Worry not. I am always looking out for you Check out below pages for awesome resources, explanations & examples on Excel lookup formulas.- Introduction to VLOOKUP formula – what is it & how to use it?
- Comprehensive guide to VLOOKUP & other lookup formulas
- VLOOKUP cheat sheet – download today
Searching for more? Consider joining our Excel School program
If you are searching for more on Excel, Advanced Excel, Dashboards so that you can become awesome at your work, please consider joining my Excel School program. This online course helps you use Excel like a pro & do awesome things at your work. The course has more than 24 hours of video training, 50 downloadable workbooks & interactive online classroom, all designed to help you become better.Click here to know more about Excel School & join us.
0 comments:
Post a Comment